📦 Petrus-Han / dify-enterprise-terraform

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187data "aws_iam_policy_document" "pod_identity_assume_role" {
  statement {
    effect = "Allow"
    principals {
      type        = "Service"
      identifiers = ["pods.eks.amazonaws.com"]
    }
    actions = [
      "sts:AssumeRole",
      "sts:TagSession"
    ]
  }
}

data "http" "ebs_csi_driver_policy" {
  url = "https://raw.githubusercontent.com/kubernetes-sigs/aws-ebs-csi-driver/master/docs/example-iam-policy.json"
}

data "http" "efs_csi_driver_policy" {
  url = "https://raw.githubusercontent.com/kubernetes-sigs/aws-efs-csi-driver/master/docs/iam-policy-example.json"
}

module "eks" {
  source  = "terraform-aws-modules/eks/aws"
  version = "~> 20.20"

  cluster_name                   = local.name
  cluster_version                = "1.30"
  cluster_endpoint_public_access = true

  vpc_id     = module.vpc.vpc_id
  subnet_ids = module.vpc.private_subnets

  cluster_addons = {
    coredns = {
      most_recent = true
    }
    kube-proxy = {
      most_recent = true
    }
    vpc-cni = {
      most_recent    = true
      before_compute = true
    }
    eks-pod-identity-agent = {
      most_recent = true
    }
    aws-ebs-csi-driver = {
      most_recent = true
    }
    aws-efs-csi-driver = {
      most_recent = true
    }
  }

  # Give the Terraform identity admin access to the cluster
  # which will allow resources to be deployed into the cluster
  enable_cluster_creator_admin_permissions = true
  authentication_mode                      = "API"

  eks_managed_node_groups = {
    core = {
      instance_types = ["m7g.xlarge"]
      ami_type       = "AL2023_ARM_64_STANDARD"
      min_size       = 3
      max_size       = 3
      desired_size   = 3
      block_device_mappings = {
        xvda = {
          device_name = "/dev/xvda"
          ebs = {
            volume_size = 100
          }
        }
      }
      labels = {
        "component" = "app"
      }
      iam_role_attach_cni_policy = true
    }

    db = {
      instance_types = ["r7g.xlarge"]
      ami_type       = "AL2023_ARM_64_STANDARD"
      min_size       = 3
      max_size       = 3
      desired_size   = 3
      block_device_mappings = {
        xvda = {
          device_name = "/dev/xvda"
          ebs = {
            volume_size = 100
          }
        }
      }
      labels = {
        "component" = "db"
      }
      iam_role_attach_cni_policy = true
    }
  }
}

resource "aws_iam_role" "ebs_csi_driver_role" {
  name               = "${module.eks.cluster_name}-ebs-csi-driver"
  assume_role_policy = data.aws_iam_policy_document.pod_identity_assume_role.json
  inline_policy {
    name = "ebs-csi-driver"
    policy = data.http.ebs_csi_driver_policy.response_body
  }
}

resource "aws_eks_pod_identity_association" "ebs_csi_driver" {
    cluster_name = module.eks.cluster_name
    namespace = "kube-system"
    service_account = "ebs-csi-controller-sa"
    role_arn = aws_iam_role.ebs_csi_driver_role.arn
}

resource "aws_iam_role" "efs_csi_driver_role" {
  name               = "${module.eks.cluster_name}-efs-csi-driver"
  assume_role_policy = data.aws_iam_policy_document.pod_identity_assume_role.json
  inline_policy {
    name = "efs-csi-driver"
    policy = data.http.efs_csi_driver_policy.response_body
  }
}

resource "aws_eks_pod_identity_association" "efs_csi_driver" {
    cluster_name = module.eks.cluster_name
    namespace = "kube-system"
    service_account = "efs-csi-controller-sa"
    role_arn = aws_iam_role.efs_csi_driver_role.arn
}

module "eks_blueprints_addons" {
  source  = "aws-ia/eks-blueprints-addons/aws"
  version = "~> 1.16"

  cluster_name      = module.eks.cluster_name
  cluster_endpoint  = module.eks.cluster_endpoint
  cluster_version   = module.eks.cluster_version
  oidc_provider_arn = module.eks.oidc_provider_arn

  create_delay_dependencies = [for group in module.eks.eks_managed_node_groups : group.node_group_arn]

  enable_metrics_server     = true
  enable_aws_load_balancer_controller = true
  enable_secrets_store_csi_driver = true
  enable_ingress_nginx = true

  ingress_nginx = {
    values = [yamlencode({
      controller = {
        service = {
          annotations = {
            "service.beta.kubernetes.io/aws-load-balancer-scheme" = "internet-facing"
            "service.beta.kubernetes.io/aws-load-balancer-nlb-target-type" = "ip"
          }
          loadBalancerClass = "service.k8s.aws/nlb"
        }
      }
    })]
  }

  tags = local.tags
}

resource "kubernetes_storage_class" "ebs-sc" {
  metadata {
    name = "ebs-sc"
  }
  storage_provisioner = "ebs.csi.aws.com"
  reclaim_policy      = "Delete"
  volume_binding_mode = "WaitForFirstConsumer"
}

data "kubernetes_service" "ingress_nginx_svc" {
  metadata {
    name = "ingress-nginx-controller"
    namespace = "ingress-nginx"
  }
}

locals {
  ingress_nginx_hostname = data.kubernetes_service.ingress_nginx_svc.status[0].load_balancer[0].ingress[0].hostname
}